摘要：
RPC Photonics公司有高品质的的工程漫射体BSDF测试数据，但它对于FRED帮助甚少，下面这个步骤描述了如何利用FRED脚本转换RPC Photonics提供的TXT文件，并将数据直接应用到FRED的Tabulated scatter 散射模型。
背景：
Thorlabs和RPC Photonics联手共同推出的新型漫射体及光束整形技术，可以解决其他技术的不足，大大改善了诸如光刻系统、有效固态照明，显示，背光，显示亮度增强和投影屏等大多数应用的性能。这项我们称之为工程漫射体（Engineered DiffusersTM）的新概念，与其他技术有许多不同。与诸如磨砂玻璃、乳色玻璃和全息元件等随机漫射体截然不同，工程漫射体要求对于每个散射中心，通常为微透镜单元，都进行控制。例如全息漫射体可以视为一组随机排列的透镜，但是通过全息曝光形成的类透镜效果只能通过静态方式进行控制：而无法单独操控每个微透镜单元，这也帮助解释了全息漫射体无法控制光的分布和轮廓。另一方面，在工程漫射体中，每个微透镜单元形成漫射体，由其凹形纵断面和在阵列中的位置所确定。同时，为了确保漫射体不受输入光束变化的影响，并且不产生衍射效果，微透镜单元的分布是随机的，根据产生相应的光束形状函数所选取的概率分布函数来确定。因此，工程漫射体同时保留了随机与确定性漫射体的优点，从而实现高性能的光束整形功能。
FRED是美国Photon Engineering 公司开发的光学工程仿真软件，其在杂散光分析中独特的算法、高效的准确性，使其与其它同类产品相比更具优势。本案例我们重点讲述如何由RPC Photonics的BSDF数据转为FRED可识别的散射数据。
图1. RPC Photonics工程漫射体结构及光束投射形状
步骤
1、 在http://www.rpcphotonics.com/bsdf-data-optical-diffusers/下载并解压BSDF数据到某一文件夹下，选择“Raw data”文件。
图2. RPC Photonics工程漫射体不同类型的散射数据
2、 将 http://fred-kb.photonengr.com/wp-content/uploads/sites/2/2015/06/constructRpcScatterFile.frs脚本文件放在步骤1中的文件下。（脚本代码放在了本文的最后）
3、 打开FRED并运行脚本文件，会输出如下“<SAMPLE>_FRED.txt”格式，<SAMPLE>即为RPC Photonics散射片数据集
例如下所示：
Sample name: EDF-C1-56
Merging data from file EDF-C1-56 0-0.txt
Finished merging RPC data for sample EDF-C1-56
FRED formatted data file: D:\FRED\散射片数据\EDF-C1-56_FRED.txt
4、 生成了FRED可识别的文件后，将散射模型导入到FRED里面
a. 创建一个新的散射库
b. 散射模型命名
c. 改变散射模型为“Tabulated BSDF”.
d. 在File框出右键选择“Replace With Data From a File”, 选择步骤三生成的数据文件（如EDF-C1-56_FRED.txt ）
e. 切换为“Varies w/angle” 选项（假定所有的RPC Photonics datasets 数据有多个测试角度。
f. 在底部的对话框中，选择透射散射、反射停并且你需要终止入射光线，
g. 点击OK
5、 数据输入后，可点击“Plot”按钮验证BSDF模型及总的散射值
脚本代码：
'#Language "WWB-COM"
Option Explicit
Sub Main
'Cleanup
ClearOutputWindow()
Print "Merging RPC Photonics BSDF Data Files"
SetTextColor(255,0,0)
Print "Note: Script should be located in the same folder as the BSDF TXT files."
Print "Note: Do not run this script multiple times without deleting the output file between executions."
SetTextColor(0,0,0)
'Current directory of this script (should be the same as the text files being merged)
Dim cDir As String
cDir = MacroDir$ & "\"
'Array which will be populated with the list of files to be merged
Dim fList() As String, curFile As String
GetFileList( cDir, fList )
Print ""
Print "Files found for merging:"
For Each curFile In fList
Print Chr(9) & curFile
Next
'Split the first text file name found to get the sample name. First file should be 0-0 measurement.
Dim nameArray() As String, sampName As String
nameArray = Split(fList(0)," 0-0.txt")
sampName = nameArray(0)
Print ""
Print "Sample name: " & Chr(9) & sampName
'Open an output file and write the FRED header data
Dim outFile As String
outFile = cDir & sampName & "_FRED.txt"
Open outFile For Output As #1
Print #1, "type bsdf_data"
Print #1, "format angles=deg bsdf=value scale=1"
'Loop the file list, skip the two header lines and write the remaining data to file
Dim lineArray() As String, curLine As Long
For Each curFile In fList
Print "Merging data from file " & curFile
ReadFile( cDir & curFile, lineArray )
For curLine = 2 To UBound(lineArray)
Print #1, lineArray(curLine)
Next
Next
'Close the output file
Close #1
Print "Finished merging RPC data for sample " & sampName
Print "FRED formatted data file: " & Chr(9) & outFile
End Sub
'Utility function to read the contents of a file into an array of strings.
Function ReadFile(ByVal fileName As String, _
ByRef lineArray() As String) As Long
ReadFile = -1
Dim oFSO As Object
Set oFSO = CreateObject("Scripting.FileSystemObject")
Erase lineArray
Dim fid As Long
If oFSO.fileexists( fileName ) Then
fid = FreeFile()
Open fileName For Input As fid
lineArray = Split(Input(LOF(fid), fid), vbCrLf)
Close fid
End If
Set oFSO = Nothing
Return UBound( lineArray )
End Function
Sub GetFileList( ByVal in_dir As String, _
ByRef in_flist() As String )
'Redimension the file list array
Erase in_flist
'Tracks how many files are found
Dim fCount As Long
fCount = 0
'Recurse directory and search for text files
Dim f As String
f = Dir$(in_dir & "*.txt")
While f <> ""
ReDim Preserve in_flist(fCount)
in_flist(fCount) = f
fCount += 1
f = Dir$()
Wend
ReDim Preserve in_flist(fCount-1)
End Sub
|
