讯技光电公司首页 最新公告:2024年讯技课程安排发布啦! 黉论教育网校|English|全站搜索|联系我们
栏目列表
FRED
VirtualLab
Macleod
GLAD
OCAD
Optiwave
LASCAD
Litestar 4D
TechwizD和TX液晶显示软件
JCMSuite
EastWave
最新发布

天文光干涉仪

双折射晶体偏振干涉效应

颜色分析

FRED应用:颜色分析

FRED应用:数字化极坐标数据

FRED应用:波片模拟

FRED应用:MTF的计算

FRED应用:LED手电筒模拟

FRED应用:模拟沃拉斯顿棱镜

FRED应用:准直透镜模拟与优

当前位置: 主页 > 服务项目 > 案例分析 > FRED >
Arizona眼睛模型
时间:2016-02-23 21:01来源:讯技光电作者: 技术部点击:打印
简介
 
人眼光学模型可用来设计眼科用设备,光学系统注定了要与人眼一起使用。本文演示了这样一个模型:Arizona眼睛模型,在Jim Schwiegerling教授的书中有详细描述:《Field Guide to Visual and Ophthalmic Optics》。AZ眼睛模型达到了基于平均临床数据所决定的轴上和轴外像差等级。FRED文件包含了此眼睛模型及几个用来分析它的光源,并包括一个基于想要的屈光度来调整模型的内嵌脚本。
 
模型
 
模型的定义如表1种所示,由半径、圆锥常数、折射率、阿贝数、到下一面的距离等一系列表面组成。一些参数由屈光度(A)来决定。
 
Table 1. AZ眼睛模型的定义
 
在FRED中使用0屈光度来创建的,光瞳加在了透镜的前面。材料是创建一个新的材料并选择类型“Model Material”,输入的参数是nd和vd.
 
光源
 
多个光源定义来分析该模型的不同特性。图1显示了所以的光源和提示信息告诉您他们可以用来做什么。
 
 
图1. 光源和提示信息使用
 
除了“Letter F”之外的所有光源的光线位置设定在了孔径光阑位置处,并增加了pre-propagation distance= -8。尽管光线在光瞳处创建,规定的传输方向相对于光线位置在pre-propagation distance之后。这意味着光束沿着Z轴在眼睛的前面以平行光入射,而不是在光瞳处入射。
 
在往下看是内置的脚本用来修改屈光度,使其为4(250mm),光源“Letter F”在视网膜处生成一个字母为F的图像。绿色的光线聚焦的非常好而红色和蓝色光线有一点的模糊。使用Positions Spot Diagram分析工具来观察最为合适。
 
图2. 字母F光源的设定方法光
 
 
图3. 字母F在视网膜上位置点列图
 
视网膜的散射
 
在散射文件中,有一个名为“Retina surface”的72%的反射型朗伯散射,它为视网膜的散射提供了一个粗略的近似。为了模拟来自视网膜的散射,改变自定义元件“Eye ball” 下的视网膜的表面从“halt all” 到”Allow All”。并使几何中“plane”可追迹。
 
 
图4. 视网膜朗伯散射设定
 
注意在视网膜的表面有散射重点采样规格定义,在“Scatter”标签的底部可获取该信息。“toward pupil”指定散射光朝向光瞳,半角度10度。
 
 
图5. 视网膜重点采样规格设定
 
脚本
 
内置脚本使用对话框显示屈光度和光瞳直径的数值设置。使用FRED Basic脚本创建和使用对话框非常容易。图6显示了如何获取用户自定义对话框,如下图所示:
 
图6. 用户对话框的创建与编辑
 
图7. 用户对话框编辑器
 
如果“OK”按钮按下,将会核对对话框下面的代码行,如果点击取消则脚本终止。然后输入的参数赋予变量,如果此处是保留为空白,则使用默认值。因此,如果没有值输入并点击“OK”按钮,则脚本是以屈光度为0,光瞳直径为4mm来运行的。
余下的脚本计算与屈光度有关的所有参数。
 
分析
 
屈光度为4,光瞳直径为4mm,字母F点在视网膜上所成的像。
 
图7. 字母F在视网膜上颜色分析
 
脚本代码
 
Option Explicit     'Remove this to enable non-dimensioned variables to be used.
 
Dim entity As T_ENTITY
Dim op As T_OPERATION
Dim mat As T_MODELMATERIAL
Dim A As Double
Dim pupilDiam As Double
Dim eID As Long
Dim parID As Long
Dim count As Integer
Dim taq As Double, Rant As Double, CCant As Double, Rpost As Double, CCpost As Double
Dim tlens As Double, nlens As Double
Dim curv As Double, conic As Double
Dim ok As Long
 
Sub Main
 
    '用户输入对话框
    Begin Dialog UserDialog 320,126,"Input parameters" ' %GRID:10,7,1,1
        TextBox 220,21,40,21,.TextBox1 'default: 0
        Text 20,21,190,21,"Accommodation (in Diopters):",.Text1,1
        OKButton 40,91,90,21
        CancelButton 190,91,90,21
        Text 20,49,190,14,"Pupil diameter (4 mm default):",.Text2,1
        TextBox 220,49,40,21,.TextBox2 'default: 4
    End Dialog
    Dim dlg As UserDialog
 
    ok = Dialog (dlg)
 
    If ok=0 Then    'cancel button was pressed
        Print "Execution cancelled."
        End
    End If
 
    'Assign accommodation and pupil diameter & use defaults if field left empty
    If dlg.TextBox1 = "" Then
        A = 0           'Default accommodation
    Else
        A = CDbl(dlg.TextBox1)
    End If
 
    If dlg.TextBox2 = "" Then
        pupilDiam = 4   'Default pupil diameter
    Else
        pupilDiam = CDbl(dlg.TextBox2)
    End If
 
    Print " "
    Print "Accommodation = " & A & " Diopters"
    Print "Pupil Diameter = " & pupilDiam & " mm"
 
    ' Calculate new parameters with accommodation
    taq = 0.55 + 2.97 - 0.04*A              'Aqueous thickness
 
    Rant = 12.0 - 0.4*A                     'Radius of anterior lens
    CCant = -7.518749 + 1.285720*A          'Conic constant of anterior lens
 
    Rpost = -5.224557 + 0.2*A               'Radius of posterior lens
    CCpost = -1.353971 - 0.431762*A         'Conic constant of posterior lens
 
    tlens = 3.767 + 0.04*A                  'Lens thickness
 
    nlens = 1.42 + 0.00256*A - 0.00022*A^2  'Lens index of refraction
 
    'Adjust parameters to account for accommodation
 
    '*************************************************************************
    'Aqueous thickness (Position of Lens)
    '*************************************************************************
    eID = FindFullName( "Geometry.Arizona Eye.Lens" )
    GetCustomElement eID, entity
 
    parID = FindFullName( "Geometry.Arizona Eye" )
 
    ' Delete any shift(s) in z
    count = 0
    While GetOperationCount(eID)>count
        GetOperation eID, count, op
        If op.Type="ShiftZ" Then
            DeleteOperation eID,count
            count=count-1
        End If
        count=count+1
    Wend
 
    'Set new shift in
    op.Type = "ShiftZ"
    op.val1 = taq
    op.parent = parID
    AddOperation eID, op
    Print "Set aqueous humor thickness = " & taq-0.55
 
    '*************************************************************************
    'Radius and conic constant of anterior lens
    '*************************************************************************
    eID = FindFullName( "Geometry.Arizona Eye.Lens.Anterior" )
    GetConic eID, entity, curv, conic
 
    SetConic eID, entity, 1/Rant, CCant
    Print "Set anterior lens radius = " & Rant & " and conic constant = " & CCant
 
    '*************************************************************************
    'Radius and conic constant of posterior lens
    '*************************************************************************
    eID = FindFullName( "Geometry.Arizona Eye.Lens.Posterior" )
    GetConic eID, entity, curv, conic
 
    SetConic eID, entity, 1/Rpost, CCpost
    Print "Set posterior lens radius = " & Rpost & " and conic constant = " & CCpost
 
    '*************************************************************************
    'Lens thickness (Position of posterior lens surface)
    '*************************************************************************
 
    parID = FindFullName( "Geometry.Arizona Eye.Lens" )
 
    ' Delete any z-shift(s)
    count = 0
    While GetOperationCount(eID)>count
        GetOperation eID, count, op
        If op.Type="ShiftZ" Then
            DeleteOperation eID,count
            count=count-1
        End If
        count=count+1
    Wend
 
    'Set new z-shift
    op.Type = "ShiftZ"
    op.val1 = tlens
    op.parent = parID
    AddOperation eID, op
    Print "Set lens thickness = " & tlens
 
    '*************************************************************************
    'Lens index of refraction
    '*************************************************************************
    eID = FindMaterial( "Lens" )
    GetModelMaterial eID, mat
 
    mat.Nd = nlens
    SetModelMaterial eID, mat
    Print "Set lens index of refraction = " & nlens
 
    '*************************************************************************
    'Pupil diameter
    '*************************************************************************
    eID = FindFullName( "Geometry.Arizona Eye.Pupil.Iris" )
 
    'Adjust pupil diameter (trimming volume inner hole)
 
    SetTrimVolHole eID, pupilDiam/2, pupilDiam/2, 0, 0, "Cylinder"
 
    ' Adjust pupil location to just in front of the lens
    parID = FindFullName( "Geometry.Arizona Eye" )
    eID = FindFullName( "Geometry.Arizona Eye.Pupil" )
    count = 0
    While GetOperationCount(eID)>count
        GetOperation eID, count, op
        If op.Type="ShiftZ" Then
            DeleteOperation eID,count
            count=count-1
        End If
        count=count+1
    Wend
    op.Type = "ShiftZ"
    op.val1 = taq-0.01
    op.parent = parID
    AddOperation eID, op
 
    Print "Set pupil diameter = " & pupilDiam
 
    'Update AZ Eye subassembly Description
    eID = FindFullName( "Geometry.Arizona Eye" )
    GetEntity eID, entity
    entity.Description = "Accommodation = " & A & "D"
    SetEntity eID, entity
 
    Update
    Print "DONE!"
    
End Sub
 
如果屈光度是4,光瞳直径是4,则会输出如下数据:
 
Accommodation = 4 Diopters
Pupil Diameter = 4 mm
Set aqueous humor thickness = 2.81
Set anterior lens radius = 10.4 and conic constant = -2.375869
Set posterior lens radius = -4.424557 and conic constant = -3.081019
Set lens thickness = 3.927
Set lens index of refraction = 1.42672
Set pupil diameter = 4
DONE!
关于我们
公司介绍
专家团队
人才招聘
讯技风采
员工专区
服务项目
产品销售
课程中心
专业书籍
项目开发
技术咨询
联系方式
地址:上海市嘉定区南翔银翔路819号中暨大厦18楼1805室    邮编:201802
电话:86-21-64860708/64860576/64860572  传真:86-21-64860709
课程:course@infotek.com.cn
业务:sales@infotek.com.cn
技术:support@infotek.com.cn
官方微信
扫一扫,关注讯技光电的微信订阅号!
Copyright © 2014-2024 讯技光电科技(上海)有限公司, All Rights Reserved. 沪ICP备10008742号-1